Add x11-terms/st-9999

x11-terms/st/Manifest

@@ -0,0 +1 @@
+EBUILD st-9999.ebuild 1370 BLAKE2B 2858a3f5abb7a121280d2fa9be4127558f6fb0b23256c6e45b05ae2734da4b5136867b2dc7b8b13b5a15f8aefcc6367d4d79b18a46eee1d2645055da482f1bfc SHA512 d6293da8ff39041fdaf5911639c89f993c46a0bff8300a05179b0dc1ae613faa35d8508305e894fc8fefcb761a74ca5149c72d142d183f942039825ece184b1c

x11-terms/st/st-9999.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop git-r3 multilib savedconfig toolchain-funcs
+
+DESCRIPTION="simple terminal implementation for X"
+HOMEPAGE="https://git.kske.dev/kske/st/"
+EGIT_REPO_URI="https://git.kske.dev/kske/st"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS=""
+IUSE="savedconfig"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}